path: root/c/src/configure.in

dnl Process this file with autoconf to produce a configure script.
dnl
dnl  $Id$

AC_PREREQ(2.13)
AC_INIT(exec)
RTEMS_TOP(../..)
AC_CONFIG_AUX_DIR(../..)

RTEMS_ENABLE_CXX
RTEMS_ENABLE_NETWORKING
RTEMS_ENABLE_RDBG

RTEMS_CANONICAL_TARGET_CPU
RTEMS_CANONICAL_HOST

AM_INIT_AUTOMAKE(rtems-c-src,$RTEMS_VERSION,no)
AM_MAINTAINER_MODE

RTEMS_ENABLE_MULTILIB
RTEMS_ENV_RTEMSBSP
RTEMS_CHECK_CPU
RTEMS_CHECK_CUSTOM_BSP(RTEMS_BSP)

RTEMS_CHECK_NETWORKING(RTEMS_BSP)

## Note: the order of the directories below is essential
cfg_subdirs1="make"

## Exclude exec from building if multilibs are enabled
if test x"$multilib" = x"no"; then
hst_subdirs1="$hst_subdirs1 exec"
fi
hst_subdirs1="$hst_subdirs1 lib"
cfg_subdirs="$cfg_subdirs lib/libcpu lib/libbsp"
hst_subdirs="libfs"
hst_subdirs="$hst_subdirs libmisc"

if test "$RTEMS_CPU" != "unix"; then
## HACK: Suppress libchip for unix
hst_subdirs="$hst_subdirs libchip"
fi

if test "$HAS_NETWORKING" = "yes"; then
  hst_subdirs="$hst_subdirs libnetworking librpc"
  if test "$RTEMS_HAS_RDBG" = "yes"; then
    RTEMS_CHECK_RDBG(RTEMS_BSP)
  fi
fi

if test "$HAS_RDBG" = "yes"; then
  hst_subdirs="$hst_subdirs librdbg"
fi
AM_CONDITIONAL(HAS_NETWORKING, test "$HAS_NETWORKING" = "yes" )
AM_CONDITIONAL(HAS_RDBG, test "$HAS_RDBG" = "yes" )

if test "$RTEMS_HAS_CPLUSPLUS" = "yes"; then
  hst_subdirs="$hst_subdirs librtems++";
fi 

RTEMS_CONFIG_HOST_SUBDIRS($hst_subdirs1)
AC_SUBST(hst_subdirs1)
RTEMS_CONFIG_HOST_SUBDIRS($hst_subdirs)
AC_SUBST(hst_subdirs)

AC_CONFIG_SUBDIRS($cfg_subdirs1)
AC_SUBST(cfg_subdirs1)
AC_CONFIG_SUBDIRS($cfg_subdirs)
AC_SUBST(cfg_subdirs)

AC_CONFIG_SUBDIRS(tests)

RTEMS_PROJECT_ROOT

RTEMS_PROG_CC_FOR_TARGET
RTEMS_CANONICALIZE_TOOLS

# Explicitly list all Makefiles here
AC_OUTPUT( 
Makefile
wrapup/Makefile,,
test -d lib || mkdir lib
)

RTEMS_OUTPUT_HOST_SUBDIRS(RTEMS_HOST_SUBDIRS)