path: root/c/src/configure.in

dnl Process this file with autoconf to produce a configure script.
dnl
dnl  $Id$

AC_PREREQ(2.13)
AC_INIT(exec)
RTEMS_TOP(../..)
AC_CONFIG_AUX_DIR(../..)

RTEMS_ENABLE_CXX
RTEMS_ENABLE_NETWORKING
RTEMS_ENABLE_RDBG

RTEMS_CANONICAL_TARGET_CPU
RTEMS_CANONICAL_HOST

AM_INIT_AUTOMAKE(rtems-c-src,$RTEMS_VERSION,no)
AM_MAINTAINER_MODE

RTEMS_ENV_RTEMSBSP
RTEMS_CHECK_CPU
RTEMS_CHECK_CUSTOM_BSP(RTEMS_BSP)

RTEMS_CHECK_NETWORKING(RTEMS_BSP)

## Note: the order of the directories below is essential
cfg_subdirs="make"
cfg_subdirs="$cfg_subdirs exec"
cfg_subdirs="$cfg_subdirs lib"
cfg_subdirs="$cfg_subdirs libmisc"

if test "$RTEMS_CPU" != "unix"; then
## HACK: Suppress libchip for unix
cfg_subdirs="$cfg_subdirs libchip"
fi

if test "$HAS_NETWORKING" = "yes"; then
  cfg_subdirs="$cfg_subdirs libnetworking librpc"
  if test "$RTEMS_HAS_RDBG" = "yes"; then
    RTEMS_CHECK_RDBG(RTEMS_BSP)
  fi
fi

if test "$HAS_RDBG" = "yes"; then
  cfg_subdirs="$cfg_subdirs librdbg"
fi
AM_CONDITIONAL(HAS_NETWORKING, test "$HAS_NETWORKING" = "yes" )
AM_CONDITIONAL(HAS_RDBG, test "$HAS_RDBG" = "yes" )

if test "$RTEMS_HAS_CPLUSPLUS" = "yes"; then
  cfg_subdirs="$cfg_subdirs librtems++";
fi 

AC_CONFIG_SUBDIRS($cfg_subdirs)
AC_SUBST(cfg_subdirs)
AC_CONFIG_SUBDIRS(tests)

RTEMS_PROJECT_ROOT

AC_OUTPUT( 
Makefile
wrapup/Makefile
)