1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
|
/* SPDX-License-Identifier: BSD-2-Clause */
/**
* @file
*
* @ingroup RTEMSScoreCPUARM
*
* @brief ARM data and prefetch abort exception prologue and epilogue.
*/
/*
* Copyright (c) 2009 embedded brains GmbH & Co. KG
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
* 1. Redistributions of source code must retain the above copyright
* notice, this list of conditions and the following disclaimer.
* 2. Redistributions in binary form must reproduce the above copyright
* notice, this list of conditions and the following disclaimer in the
* documentation and/or other materials provided with the distribution.
*
* THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
* AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
* ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
* LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
* CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
* SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
* INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
* CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
* ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
* POSSIBILITY OF SUCH DAMAGE.
*/
#ifdef HAVE_CONFIG_H
#include "config.h"
#endif
#include <rtems/asm.h>
#ifdef ARM_MULTILIB_ARCH_V4
.extern _ARM_Exception_default
.globl _ARMV4_Exception_data_abort_set_handler
.globl _ARMV4_Exception_data_abort
.globl _ARMV4_Exception_prefetch_abort_set_handler
.globl _ARMV4_Exception_prefetch_abort
.section ".bss"
data_abort_handler:
.long 0
prefetch_abort_handler:
.long 0
.section ".text"
#ifdef __thumb__
.thumb_func
#endif
_ARMV4_Exception_data_abort_set_handler:
ldr r1, =data_abort_handler
str r0, [r1]
#ifdef __thumb__
bx lr
#else
mov pc, lr
#endif
#ifdef __thumb__
.thumb_func
#endif
_ARMV4_Exception_prefetch_abort_set_handler:
ldr r1, =prefetch_abort_handler
str r0, [r1]
#ifdef __thumb__
bx lr
#else
mov pc, lr
#endif
.arm
_ARMV4_Exception_prefetch_abort:
/* Save context and load handler */
sub sp, #20
stmdb sp!, {r0-r12}
mov r4, #3
ldr r6, =prefetch_abort_handler
b save_more_context
_ARMV4_Exception_data_abort:
/* Save context and load handler */
sub sp, #20
stmdb sp!, {r0-r12}
mov r4, #4
ldr r6, =data_abort_handler
save_more_context:
/* Save more context */
mov r2, lr
mrs r3, spsr
mrs r7, cpsr
orr r5, r3, #ARM_PSR_I
bic r5, #ARM_PSR_T
msr cpsr, r5
mov r0, sp
mov r1, lr
msr cpsr, r7
add r5, sp, #72
stmdb r5!, {r0-r4}
/* Call high level handler */
ldr r2, [r6]
cmp r2, #0
ldreq r2, =_ARM_Exception_default
mov r0, sp
#ifndef __thumb__
mov lr, pc
mov pc, r2
#else /* __thumb__ */
SWITCH_FROM_ARM_TO_THUMB r1
bl call_handler
SWITCH_FROM_THUMB_TO_ARM
#endif /* __thumb__ */
/* Restore context */
ldmia r5!, {r0-r4}
mov lr, r2
msr spsr, r3
ldmia sp!, {r0-r12}
add sp, #20
/* Return from interrupt */
subs pc, lr, #8
#ifdef __thumb__
.thumb
call_handler:
bx r2
#endif /* __thumb__ */
#endif /* ARM_MULTILIB_ARCH_V4 */
|
