1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
|
/* SPDX-License-Identifier: BSD-2-Clause */
/**
* @file
*
* @brief bsp_start_memcpy() implementation.
*/
/*
* Copyright (C) 2008, 2011 embedded brains GmbH & Co. KG
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
* 1. Redistributions of source code must retain the above copyright
* notice, this list of conditions and the following disclaimer.
* 2. Redistributions in binary form must reproduce the above copyright
* notice, this list of conditions and the following disclaimer in the
* documentation and/or other materials provided with the distribution.
*
* THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
* AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
* ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
* LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
* CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
* SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
* INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
* CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
* ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
* POSSIBILITY OF SUCH DAMAGE.
*/
#include <rtems/asm.h>
#include <rtems/score/cpu.h>
.section ".bsp_start_text", "ax"
#if defined(ARM_MULTILIB_ARCH_V4)
DEFINE_FUNCTION_ARM(bsp_start_memcpy)
/* Return if dest == src */
cmp r0, r1
#ifdef __thumb__
bxeq lr
#else
moveq pc, lr
#endif
/* Return if length is zero */
mov r3, #0
cmp r3, r2
#ifdef __thumb__
bxeq lr
#else
moveq pc, lr
#endif
/* Save non-volatile registers */
push {r4-r8, lr}
/* Copy worker routine to stack */
adr ip, worker_begin
ldm ip, {r3-r8}
push {r3-r8}
#ifdef ARM_MULTILIB_HAS_BARRIER_INSTRUCTIONS
dsb
isb
#endif
/* Execute worker routine */
mov r3, #0
mov ip, sp
mov lr, pc
#ifdef __thumb__
bx ip
#else
mov pc, ip
#endif
/* Restore stack and non-volatile registers */
add sp, sp, #24
pop {r4-r8, lr}
/* Return */
#ifdef __thumb__
bx lr
#else
mov pc, lr
#endif
worker_begin:
/* Worker routine */
ldr ip, [r1, r3]
str ip, [r0, r3]
add r3, r3, #4
cmp r3, r2
bcc worker_begin
#ifdef __thumb__
bx lr
#else
mov pc, lr
#endif
#elif defined(ARM_MULTILIB_ARCH_V7M)
.syntax unified
.align 2
.globl bsp_start_memcpy
.thumb
.thumb_func
.type bsp_start_memcpy, %function
bsp_start_memcpy:
/* Return if dest == src */
cmp r0, r1
beq return
/* Return if length is zero */
movs r3, #0
cmp r3, r2
beq return
/* Save non-volatile registers */
push {r4-r7, lr}
/* Copy worker routine to stack */
adr r3, worker_begin
ldm r3, {r4-r7}
push {r4-r7}
/* Execute worker routine */
add r3, sp, #1
adds r2, r2, #3
bic r2, r2, #3
adds r2, r2, r1
blx r3
/* Restore stack and non-volatile registers */
add sp, sp, #16
pop {r4-r7, lr}
return:
/* Return */
bx lr
.align 2
worker_begin:
/* Worker routine */
ldr r3, [r1], #4
cmp r2, r1
str r3, [r0], #4
bne worker_begin
bx lr
#endif /* defined(ARM_MULTILIB_ARCH_V7M) */
|