Added ka9q tcpip stack and network driver for the gen68360. This effort

was done based on the 3.6.0 release and had to be autoconf'ed locally.
It is turned on is the bsp enables it and it is not explicitly disabled
via the configure option --disable-tcpip.   As many warnings as possible
were removed locally after the code was merged.  Only the gen68360
and mvme136 bsps were compiled this way.

The ka9q port and network driver were submitted by Eric Norum
(eric@skatter.USask.Ca).

The network demo programs are not included in the tree at this point.

3 files changed, 242 insertions, 23 deletions

diff --git a/c/src/lib/libbsp/m68k/gen68360/startup/linkcmds b/c/src/lib/libbsp/m68k/gen68360/startup/linkcmds
index 8869c380a7..6a2d950853 100644
--- a/c/src/lib/libbsp/m68k/gen68360/startup/linkcmds
+++ b/c/src/lib/libbsp/m68k/gen68360/startup/linkcmds
@@ -1,5 +1,7 @@
 /*
- *  This file contains GNU linker directives for a generic MC68360 board.
+ * This file contains GNU linker directives for a generic MC68360 board.
+ * Variations in hardware type and dynamic memory size can be made
+ * by overriding some values with linker command-line arguments.
  *
  * Saskatchewan Accelerator Laboratory
  * University of Saskatchewan
@@ -10,32 +12,64 @@
  */
 
 /*
- * Declare on-board memory
+ * Declare some sizes.
+ * XXX: The assignment of ". += XyzSize;" fails in older gld's if the
+ *      number used there is not constant.  If this happens to you, edit
+ *      the lines marked XXX below to use a constant value.
+ */
+RamSize = DEFINED(RamSize) ? RamSize : 4M;
+HeapSize = DEFINED(HeapSize) ? HeapSize : 0x10000;
+StackSize = DEFINED(StackSize) ? StackSize : 0x1000;
+
+/*
+ * Declare hardware type
+ */
+MC68360HardwareTypeMotorolaGeneric = 0; 
+MC68360HardwareTypeAtlasHSB = 1; 
+MC68360HardwareType = DEFINED(MC68360HardwareType) ? MC68360HardwareType : 0;
+
+/*
+ * Declare on-board memory.
+ * It would be nice if the ram length could be given as
+ * LENGTH=RamSize, but gld doesn't allow non-constant
+ * values in the LENGTH expression.  
  */
 MEMORY {
-          ram : ORIGIN = 0x00000000, LENGTH = 4M
+          ram : ORIGIN = 0x00000000, LENGTH = 64M
           rom : ORIGIN = 0xFF000000, LENGTH = 1M
         dpram : ORIGIN = 0xFE000000, LENGTH = 8k
 }
 
 /*
- * Declare some sizes
- * XXX: The assignment of ". += XyzSize;" fails in older gld's if the
- *      number used there is not constant.  If this happens to you, edit
- *      the lines marked below to use a constant value.
+ * Declare low-order three octets of Ethernet address.
  */
-HeapSize = DEFINED(HeapSize) ? HeapSize : 0x10000;
-StackSize = DEFINED(StackSize) ? StackSize : 0x1000;
+ETHERNET_ADDRESS = DEFINED(ETHERNET_ADDRESS) ? ETHERNET_ADDRESS : 0xDEAD12;
 
 /*
- * Declare low-order three octets of Ethernet address
+ * Declare hardware type.
+ * Acceptable values are:
+ *	0 - Generic system as described in the MC68360 User's Manual
+ *	    (MC68360UM/AD Rev. 1).
+ *	1 - ATLAS Computer Equipment Incorporated ACE360/HSB.
  */
-ETHERNET_ADDRESS = DEFINED(ETHERNET_ADDRESS) ? ETHERNET_ADDRESS : 0xDEAD12;
+MC68360HardwareType = DEFINED(MC68360HardwareType) ? MC68360HardwareType : 0;
 
 /*
  * Load objects
  */
 SECTIONS {
+	/*
+	 * Hardware variations
+	 */
+	_RamSize = RamSize;
+	__RamSize = RamSize;
+	_MC68360HardwareType = MC68360HardwareType;
+	__MC68360HardwareType = MC68360HardwareType;
+	_MC68360HardwareTypeMotorolaGeneric = MC68360HardwareTypeMotorolaGeneric; 
+	__MC68360HardwareTypeMotorolaGeneric = MC68360HardwareTypeMotorolaGeneric; 
+	_MC68360HardwareTypeAtlasHSB = MC68360HardwareTypeAtlasHSB; 
+	__MC68360HardwareTypeAtlasHSB = MC68360HardwareTypeAtlasHSB; 
+
         /*
          * Boot PROM
          */
diff --git a/c/src/lib/libbsp/m68k/gen68360/startup/linkcmds.bootp b/c/src/lib/libbsp/m68k/gen68360/startup/linkcmds.bootp
new file mode 100644
index 0000000000..0fb1008376
--- /dev/null
+++ b/c/src/lib/libbsp/m68k/gen68360/startup/linkcmds.bootp
@@ -0,0 +1,146 @@
+/*
+ * This file contains GNU linker directives for a generic MC68360 board.
+ * Variations in hardware type and dynamic memory size can be made
+ * by overriding some values with linker command-line arguments.
+ *
+ * These linker directives are for producing a PROM version.
+ * To create the PROM image from the linker output you must use objcopy
+ * (--adjust-section-vma) to place the data segment at the end of the text
+ * segment in the PROM.  The start-up code takes care of copying this region
+ * to RAM.
+ *
+ * Saskatchewan Accelerator Laboratory
+ * University of Saskatchewan
+ * Saskatoon, Saskatchewan, CANADA
+ * eric@skatter.usask.ca
+ * 
+ *  $Id$
+ */
+
+/*
+ * Declare some sizes.
+ * XXX: The assignment of ". += XyzSize;" fails in older gld's if the
+ *      number used there is not constant.  If this happens to you, edit
+ *      the lines marked XXX below to use a constant value.
+ */
+RamSize = DEFINED(RamSize) ? RamSize : 4M;
+HeapSize = DEFINED(HeapSize) ? HeapSize : 0x10000;
+StackSize = DEFINED(StackSize) ? StackSize : 0x1000;
+
+/*
+ * Declare hardware type
+ */
+MC68360HardwareTypeMotorolaGeneric = 0; 
+MC68360HardwareTypeAtlasHSB = 1; 
+MC68360HardwareType = DEFINED(MC68360HardwareType) ? MC68360HardwareType : 0;
+
+/*
+ * Declare on-board memory.
+ * It would be nice if the ram length could be given as
+ * LENGTH=RamSize, but gld doesn't allow non-constant
+ * values in the LENGTH expression.  
+ */
+MEMORY {
+          ram : ORIGIN = 0x00000000, LENGTH = 64M
+        myram : ORIGIN = 4M-512k,    LENGTH = 512k
+          rom : ORIGIN = 0xFF000000, LENGTH = 1M
+        dpram : ORIGIN = 0xFE000000, LENGTH = 8k
+}
+
+/*
+ * Declare low-order three octets of Ethernet address.
+ */
+ETHERNET_ADDRESS = DEFINED(ETHERNET_ADDRESS) ? ETHERNET_ADDRESS : 0xDEAD12;
+
+/*
+ * Declare hardware type.
+ * Acceptable values are:
+ *	0 - Generic system as described in the MC68360 User's Manual
+ *	    (MC68360UM/AD Rev. 1).
+ *	1 - ATLAS Computer Equipment Incorporated ACE360/HSB.
+ */
+MC68360HardwareType = DEFINED(MC68360HardwareType) ? MC68360HardwareType : 0;
+
+/*
+ * Load objects
+ */
+SECTIONS {
+	/*
+	 * Hardware variations
+	 */
+	_RamSize = RamSize;
+	__RamSize = RamSize;
+	_MC68360HardwareType = MC68360HardwareType;
+	__MC68360HardwareType = MC68360HardwareType;
+	_MC68360HardwareTypeMotorolaGeneric = MC68360HardwareTypeMotorolaGeneric; 
+	__MC68360HardwareTypeMotorolaGeneric = MC68360HardwareTypeMotorolaGeneric; 
+	_MC68360HardwareTypeAtlasHSB = MC68360HardwareTypeAtlasHSB; 
+	__MC68360HardwareTypeAtlasHSB = MC68360HardwareTypeAtlasHSB; 
+
+        /*
+         * Boot PROM
+         */
+        rom : {
+                _RomBase = .;
+                __RomBase = .;
+        } >rom
+
+        /*
+         * Dynamic RAM
+         */
+        ram : {
+                _RamBase = .;
+                __RamBase = .;
+        } >ram
+
+        /*
+         * Text, data and bss segments
+         */
+        .text : AT (0x00000000) {
+                CREATE_OBJECT_SYMBOLS
+                *(.text)
+                . = ALIGN (16);
+                etext = .;
+                _etext = .;
+        } >rom 
+        .data : AT(SIZEOF(.text)) {
+                copy_start = .;
+                *(.data)
+                . = ALIGN (16);
+                _edata = .;
+                copy_end = .;
+        } >myram
+        .bss : {
+                M68Kvec = .;
+                _M68Kvec = .;
+                . += (256 * 4);
+                clear_start = .;
+                *(.bss)
+                *(COMMON)
+                . = ALIGN (16);
+                _end = .;
+
+                _HeapStart = .;
+                __HeapStart = .;
+                . += HeapSize;  /* XXX -- Old gld can't handle this */
+                . += StackSize; /* XXX -- Old gld can't handle this */
+                /* . += 0x10000; */ /* HeapSize for old gld */
+                /* . += 0x1000;  */ /* StackSize for old gld */
+                . = ALIGN (16);
+                stack_init = .;
+                clear_end = .;
+
+                _WorkspaceBase = .;
+                __WorkspaceBase = .;
+        } >myram
+
+        /*
+         * On-chip memory/peripherals
+         */
+        dpram : {
+                m360 = .;
+                _m360 = .;
+                . += (8 * 1024);
+
+        } >dpram
+}
diff --git a/c/src/lib/libbsp/m68k/gen68360/startup/linkcmds.prom b/c/src/lib/libbsp/m68k/gen68360/startup/linkcmds.prom
index ef1c3ee6e2..64d5fe91a1 100644
--- a/c/src/lib/libbsp/m68k/gen68360/startup/linkcmds.prom
+++ b/c/src/lib/libbsp/m68k/gen68360/startup/linkcmds.prom
@@ -1,7 +1,10 @@
 /*
  * This file contains GNU linker directives for a generic MC68360 board.
- * These linker directives are for producing a PROM version..
- * To create the PROM image from the linkter output you must use objcopy
+ * Variations in hardware type and dynamic memory size can be made
+ * by overriding some values with linker command-line arguments.
+ *
+ * These linker directives are for producing a BOOTP PROM.
+ * To create the PROM image from the linker output you must use objcopy
  * (--adjust-section-vma) to place the data segment at the end of the text
  * segment in the PROM.  The start-up code takes care of copying this region
  * to RAM.
@@ -20,29 +23,64 @@
 OUTPUT_FORMAT(coff-m68k)
 
 /*
- * Declare on-board memory
+ * Declare some sizes.
+ * XXX: The assignment of ". += XyzSize;" fails in older gld's if the
+ *      number used there is not constant.  If this happens to you, edit
+ *      the lines marked XXX below to use a constant value.
+ */
+RamSize = DEFINED(RamSize) ? RamSize : 4M;
+HeapSize = DEFINED(HeapSize) ? HeapSize : 0x10000;
+StackSize = DEFINED(StackSize) ? StackSize : 0x1000;
+
+/*
+ * Declare hardware type
+ */
+MC68360HardwareTypeMotorolaGeneric = 0; 
+MC68360HardwareTypeAtlasHSB = 1; 
+MC68360HardwareType = DEFINED(MC68360HardwareType) ? MC68360HardwareType : 0;
+
+/*
+ * Declare on-board memory.
+ * It would be nice if the ram length could be given as
+ * LENGTH=RamSize, but gld doesn't allow non-constant
+ * values in the LENGTH expression.  
  */
 MEMORY {
-          ram : ORIGIN = 0x00000000, LENGTH = 4M
+          ram : ORIGIN = 0x00000000, LENGTH = 64M
           rom : ORIGIN = 0xFF000000, LENGTH = 1M
         dpram : ORIGIN = 0xFE000000, LENGTH = 8k
 }
 
 /*
- * Declare some sizes
+ * Declare low-order three octets of Ethernet address.
  */
-HeapSize = DEFINED(HeapSize) ? HeapSize : 0x10000;
-StackSize = DEFINED(StackSize) ? StackSize : 0x1000;
+ETHERNET_ADDRESS = DEFINED(ETHERNET_ADDRESS) ? ETHERNET_ADDRESS : 0xDEAD12;
 
 /*
- * Declare low-order three octets of Ethernet address
+ * Declare hardware type.
+ * Acceptable values are:
+ *	0 - Generic system as described in the MC68360 User's Manual
+ *	    (MC68360UM/AD Rev. 1).
+ *	1 - ATLAS Computer Equipment Incorporated ACE360/HSB.
  */
-ETHERNET_ADDRESS = DEFINED(ETHERNET_ADDRESS) ? ETHERNET_ADDRESS : 0xDEAD12;
+MC68360HardwareType = DEFINED(MC68360HardwareType) ? MC68360HardwareType : 0;
 
 /*
  * Load objects
  */
 SECTIONS {
+	/*
+	 * Hardware variations
+	 */
+	_RamSize = RamSize;
+	__RamSize = RamSize;
+	_MC68360HardwareType = MC68360HardwareType;
+	__MC68360HardwareType = MC68360HardwareType;
+	_MC68360HardwareTypeMotorolaGeneric = MC68360HardwareTypeMotorolaGeneric; 
+	__MC68360HardwareTypeMotorolaGeneric = MC68360HardwareTypeMotorolaGeneric; 
+	_MC68360HardwareTypeAtlasHSB = MC68360HardwareTypeAtlasHSB; 
+	__MC68360HardwareTypeAtlasHSB = MC68360HardwareTypeAtlasHSB; 
+
         /*
          * Boot PROM
          */
@@ -88,8 +126,10 @@ SECTIONS {
 
                 _HeapStart = .;
                 __HeapStart = .;
-                . += HeapSize;
-                . += StackSize;
+                . += HeapSize;  /* XXX -- Old gld can't handle this */
+                . += StackSize; /* XXX -- Old gld can't handle this */
+                /* . += 0x10000; */ /* HeapSize for old gld */
+                /* . += 0x1000;  */ /* StackSize for old gld */
                 . = ALIGN (16);
                 stack_init = .;
                 clear_end = .;
@@ -107,5 +147,4 @@ SECTIONS {
                 . += (8 * 1024);
 
         } >dpram
-
 }